Visual2000 · Архив статей А.Колесова & О.Павловой

Советы тем, кто программирует на Visual Basic

Андрей Колесов, Ольга Павлова

• Совет 119. Используйте функции API для перекодировки текста.
• Совет 120. Простые процедуры преобразования символьных данных.
• Совет 121. Будьте внимательны при преобразовании исходных текстов программ из DOS в Windows, и наоборот.

В этот выпуск мы включили несколько советов, связанных с перекодировкой строковых переменных.

Совет 119. Используйте функции API для перекодировки текста.

При решении многих задач требуется выполнить перекодировку текста из одной кодовой таблицы в другую, например из 866 в 1251, или наоборот. Чтобы справиться с этой проблемой, можно обратиться к соответствующим функциям API.

Напомним, что Windows 3.x/95 использует в своей работе две кодовые таблицы, которые мы обычно называем DOS и Windows, но формально они именуются OEM и ANSI. Именно последние названия используются в соответствующих именах параметров управляющих файлов Windows. Для отечественных пользователей эти таблицы имеют номера 866 и 1251 соответственно. (Чтобы не вводить своих пользователей в искушение, Microsoft не позволяет производить динамическое переопределение номеров кодовых таблиц — они устанавливаются только при инсталляции ОС. Впрочем, смельчаки могут отважиться и на это, непосредственно изменив параметры управляющих файлов, что вполне возможно, но... лучше не играть с огнем.)

В составе API есть процедуры преобразования кодировки из OEM-таблицы в ANSI, и наоборот. В 32-разрядном наборе интерес представляют прежде всего следующие функции:

CharToOem — преобразование строковой переменной из ANSI в OEM (в API/16 аналогичная функция называется AnsiToOem);

OemToChar — преобразование строковой переменной из OEM в ANSI (API/16 — OemToAnsi);

В API 16/32 есть и другие функции, связанные с преобразованием символьных данных. Их применение можно проиллюстрировать таким примером (API/32):

Private Declare Function GetOEMCP Lib "kernel32" () As Long
Private Declare Function GetACP Lib "kernel32" () As Long
Private Declare Function OemToChar Lib "user32" Alias "OemToCharA"
(ByVal lpszSrc As String, ByVal lpszDst As String) As Long

Private Sub Form_Load()
   ' сначала можно проверить номера кодовых таблиц
   OemCP& = GetOEMCP    ' номер OEM (DOS) таблицы
   AnsiCP& = GetACP     ' номер ANSI (Windows) таблицы
   Debug.Print OemCP&; AnsiCP&   ' = 866 2151
   '
   ' открывает файл с русским текстом
   FilePath$ = "russian.txt"
   Open FilePath$ For Input As #1
   Line Input #1, InputStr$
   Print InputStr$
   OutputStr$ = Space$(Len(InputStr$)) ' ВНИМАНИЕ НА ЭТУ СТРОЧКУ
   Code& = OemToChar(InputStr$, OutputStr$)  '
   '
   Print Code&: Print InputStr$: Print OutputStr$
   Close #1
End Sub

Здесь нужно обратить внимание на следующие моменты:

1. Данная функция производит перекодировку из установленной кодовой таблицы DOS в таблицу Windows. Если вы пользуетесь американской Windows OSR2, то в ней, скорее всего, не установлены страницы 866 и 1251.

2. Переменная OutputStr$, в которую записывается результат операции, должна быть сформирована до обращения к функции OemToChar. Если она вообще не была создана (в случае, например, комментария в строке OutputStr$=...), то выдается код Code& = 0. Если данная переменная существует, то получаем Code& = 1. Но при этом формируется только то число символов, которое было изначально определено. Для эксперимента установите: OutputStr$ = Space$(0) или OutputStr$ =Space$(Len(InputStr$)) + "fffffff".

3. Если вы не боитесь потерять исходное значение переменной, то проще использовать одну и ту же переменную: Code& = OemToChar(InputStr$, InputStr$).

В начало статьи

Совет 120. Простые процедуры преобразования символьных данных.

Проблемы перекодировки не ограничиваются только преобразованием из таблиц DOS в Windows. Для их решения хотелось бы предложить некоторые простые процедуры, которые сохранились у нас еще со времен QuickBasic 4.x:

FUNCTION SymChange$ (Text$, NewCode$, OldCode$)
'
'  Перекодировка символов  OldCode$ -> NewCode$:
'  в переменной Text$ все символы набора OldCode$
'  заменяются на соответствующие символы набора NewCode$
'
'  ВНИМАНИЕ!
'  Должно выполняться условие:  LEN(NewCode$)=LEN(OldCode$)
'——————————————-
     Sym$ = Text$: Ltext% = LEN(Text$)
     IF Ltext% > 0 THEN
       FOR i% = 1 TO Ltext%
         k% = INSTR(OldCode$, MID$(Text$, i%, 1))
         IF k% > 0 THEN 
           MID$(Sym$, i%, 1) = MID$(NewCode$, k%, 1)
         END IF
       NEXT i%
     END IF
     SymChange$ = Sym$
END FUNCTION

FUNCTION RusDosWin$ (Text$, Code%)
'
'  Преобразование КИРИЛЛИЦЫ:
'  Code% = 0 - из DOS в Windows
'        = 1 - обратно
'—————————————
'  D$ - константа кодов русских символов для DOS (cp866)
'  W$ - константа кодов русских символов для Windows (cp1251)
'  обе константы содержат такую последовательность символов:
'  АБВ...Яабв...я
'
'============================================
CONST D$ = "ЂЃ‚ѓ„…†‡€‰Љ‹ЊЌЋЏђ‘’“”•–—�™љ›њќћџ_
 ЎўЈ¤Ґ¦§Ё©Є«¬­®Їабвгдежзийклмноп"
CONST W$ = "АБВГДЕЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ_
абвгдежзийклмнопрстуфхцчшщъыьэюя"
' ============================================
IF Code% = 0 THEN
      RusDosWin$ = SymChange(Text$, W$, D$)
    ELSE
      RusDosWin$ = SymChange(Text$, D$, W$)
    END IF
END FUNCTION
FUNCTION ULrus$ (Text$, Code%)
'
'   Преобразование русских символов:
'   Code% = 0  - строчные в прописные
'         = 1  - наоборот
'         ELSE - ничего не делаем
'   (Аналог операторов UCASE$/LCASE$, но для русских символов)
'———————————————
     CONST Urus$ = "ЙЦУКЕНГШЩЗХФЫВАПРОЛДЖЭЯЧСМИТЬБЮЪ"
     CONST Lrus$ = "йцукенгшщзхфывапролджэячсмитьбюъ"
'
     SELECT CASE Code%
      CASE 0: ULrus$ = SymChange$(Text$, Urus$, Lrus$)
      CASE 1: ULrus$ = SymChange$(Text$, Lrus$, Urus$)
     END SELECT
END FUNCTION

FUNCTION DoubleSpaceDelete$ (Text$)
'
'   Убирает двойные пробелы в переменной Text$
'———————————
  Temp$ = RTRIM$(Text$)
  DO
    Num% = INSTR(Temp$, "  ")  ' поиск двойного пробела
    IF Num% <= 0 THEN EXIT DO
    Temp$ = LEFT$(Temp$, Num%) + MID$(Temp$, Num% + 2)
  LOOP
  DoubleSpaceDelete$ = Temp$
END FUNCTION

FUNCTION StrFilter$ (Text$, Filter$)
'================================================================
'   Фильтрация содержимого Text$
'
'   Filter$=CHR$(CodeFilter%)+FilterString$
'   Первый символ переменной Filter$ - код операции,
'   остальные символы - перечень допустимых/НЕдопустимых символов
'   CodeFilter%=ASC(Filter$)
'      =0 - удаление всех символов из Text$, кроме указанных в
'               списке допустимых - FilterString$
'      =1 - удаление всех символов из Text$, указанных в
'               списке НЕдопустимых - FilterString$
'===============================================================
      Temp$ = "": CodeFilter% = ASC(Filter$)
      FOR i% = 1 TO LEN(Text$)
        Sym$ = MID$(Text$, i%, 1)
        IF (SGN(INSTR(2, Filter$, Sym$)) XOR CodeFilter%) <> 0 THEN
          Temp$ = Temp$ + Sym$
        END IF
      NEXT i%
      StrFilter$ = Temp$
END FUNCTION

Эти процедуры представлены в формате Basic/DOS (операторы языка написаны прописными буквами) и наглядно демонстрируют преемственность исходных текстов версий DOS/Windows — для VB/Win нужно только удалить операторы DECLARE.

1. Функция StrChange$. С ее помощью можно производить замену того или иного набора символов на любой другой. Например, в строке можно поменять местами буквы "т" и "м":

   a$ = "там"
   b$ = SymChange$(a$, "тм", "мт")
   PRINT b$  ' напечатано - "мат"
   

2. Функции RusDosWin$ и ULrus$ представляют собой примеры практического применения функции StrChange$. Первая производит преобразование русских символов из кодировки DOS в Windows и наоборот, а вторая — строчных русских символов в прописные, и наоборот. Набор русских символов в кодировке DOS и Windows (константа W$) очень просто получить программным образом:

   W$ = "": D$ = ""
   For i = 192 To 255: W$ = W$ + Chr$(i): Next
   For i = 128 To 175: D$ = D$ + Chr$(i): Next
   For i = 224 To 236: D$ = D$ + Chr$(i): Next
   Print W$: Print D$
   

3. Функция DoubleSpaceDelete$ убирает лишние пробелы в строке (в качестве разделителя слов остается один пробел).

4. Функция StrFilter$ удаляет допустимые или недопустимые символы из строковой переменной в соответствии с заданным пользователем набором символов. Например, с ее помощью можно убрать все разделители из номера телефона, чтобы представить его в чисто цифровом виде:

   PhoneNumber$ = "369-76-97"
   CodeFilter% = 0       ' код операции
   FilterString$ = "1234567890"
   Filter$ = CHR$(CodeFilter%) + FilterString$
   NewNumber$ = StrFilter$(PhoneNumber$, Filter$)
   PRINT NewNumber$
   ' напечатано: '3697697'
   

В начало статьи

Совет 121. Будьте внимательны при преобразовании исходных текстов программ из DOS в Windows, и наоборот.

Многие процедуры, написанные в версиях Basic для DOS, могут применяться и в VB/Win. Но при переносе исходных программных модулей из DOS в Windows (и наоборот) нужно быть очень внимательным. И особенно в том случае, если вы хотите, чтобы одна и та же копия модуля могла использоваться в обеих версиях. Проблема здесь заключается в следующем: DOS и Windows используют разные кодировки русских букв — таблицы с номерами 866 и 1251 соответственно.

Если напрямую загрузить написанный в DOS модуль в VB, то очевидно, что русский текст, например комментарии, превратится в нечитаемый набор символов. Если вы работаете только в VB/Win, то такой исходный файл, конечно же, лучше сначала преобразовать из кодировки 866 в 1251. Для этого можно, к примеру, использовать WinWord: прочитать исходный файл как "Текст MS-DOS", а запомнить как "Только текст". Впрочем, если вопрос касается только тех комментариев, которые вам не очень-то и нужны, то такое преобразование можно не делать, а работать с одним исходным файлом как в DOS, так и в Windwos.

Другое дело, если русские символы используются непосредственно в коде программы. Самый простой пример: Print "Привет, Коля!" В этом случае перекодировка исходного текста процедуры является просто необходимой. Как следствие, одну и ту же копию программного модуля, использующего подобные символьные константы, нельзя применять при работе и в DOS и в Windows.

В то же время может возникнуть и другая ситуация, примером которой является текст приведенной выше функции RusDosWin$. Дело в том, что используемые в ней константы D$ и W$ являются не осмысленным текстом, а кодовыми таблицами, представленными для удобства в символьном виде. Каждая константа содержит коды символов последовательности "АБ...Яаб...я" для кодировки DOS и Windows соответственно. Поэтому, если смотреть текст процедуры RusDosWin$ в среде DOS, вы должны увидеть:

Const D$ = "АБ...Яаб...я"
Const W$ = хаотичный набор символов

а если в Windows, то наоборот:

Const D$ = хаотичный набор символов (но другой!)
Const W$ = "АБ...Яаб...я"

При этом вас не должен смущать появляющийся в изображении хаотичный набор символов повторяющихся знаков — просто для изображения разных кодов, не используемых реально для вывода, применяются одни и те же знаки.

Хотелось бы обратить внимание, что при написании процедуры RusDosWin$ в среде DOS в редакторе QB была введена с клавиатуры только константа D$, а константа W$ появляется в нем совершенно иным способом. Для этого в "Лексиконе>"для DOS был сделан отдельный текстовый файл, содержащий D$. Затем этот файл прочитали в WinWord как "Текст MS-DOS", сделали единственное изменение — D$ на W$ — и сохранили как "Только текст". Прочитав новый файл в DOS, можно увидеть, что он содержит константу W$. Если же набирать текст в Windows, то делается аналогичная операция преобразования, но при этом с клавиатуры вводится уже содержимое W$.

Из вышесказанного можно сделать два вывода:

1. Нельзя преобразовывать исходный текст процедур типа RusDosWin$ из одной кодировки в другую. Вернее так: можно преобразовывать комментарии, нужно преобразовывать константы типа "Привет, Коля!" (это касается, например, констант Urus$ и Lrus$ в процедуре ULrus$), но нельзя преобразовывать специальные кодовые последовательности, представленные в виде символьных констант. Соответственно, перевод файла с процедурой RusDosWin$ из DOS в Windows необходимо сделать в два этапа: весь текст перекодировать обычным образом, а потом перенести в него строки с D$ и W$ без перекодировки.

2. Если вы захотите создать файл с процедурой RusDosWin$ из приведенного выше листинга, то можно ввести с клавиатуры только константу D$ (при работе в DOS) или W$ (в Windows), а вторую константу создать самостоятельно, выполнив, например, приведенную выше операцию.

Примечание. Чтобы разобраться, почему при распечатке листинга разным символам в кодировке DOS соответствуют одни и те же символы в кодировке Windows, наберите в редакторе для DOS файл с тестом:

АБВГДЕЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ

АБВГДЕЖЗИЙКЛМНОПР''""ХЦЧШЩЪЫЬЭЮЯ

Такое несоответствие объясняется очень просто: символы с кодом 145 и 146 (в DOS — C и Т) означают левую и правую одиночную кавычку, которые при записи в режиме "текст" заменяются на стандартную одиночную кавычку с кодом 39. А все потому, что в DOS был один код кавычки, а в Windows — три (старая оставлена для совместимости)! То же самое происходит и с двойной кавычкой (34, 147, 148).

В начало статьи